Twitterの@つき投稿をiPodに通知

Twitterの@つきで自分が呼ばれた時に手持ちのiPodに通知するのは自作スクリプトでやってます。サービスはim.kayac.comという汎用の通知サービスを使用しています。
スクリプト中身はこんな感じ↓(im.kayac.comの認証なしの場合)

#!/usr/bin/perl
use strict;
use warnings;

use AnyEvent;
use AnyEvent::Twitter::Stream;
use AnyEvent::HTTP;
use HTML::Entities;
use HTTP::Request::Common;

my $kayac_user = 'im.kayac.comユーザー名';

my $cv = AnyEvent->condvar;

my $listener = AnyEvent::Twitter::Stream->new(
    consumer_key    => "a",
    consumer_secret => "b",
    token           => "c",
    token_secret    => "d",
    method          => "userstream",
    on_tweet => sub {
        my $tweet = shift;
        return unless $tweet->{text};
        if ( $tweet->{text} =~ /\@tkimuranet/ ) {
            my $req = POST "http://im.kayac.com/api/post/$kayac_user", [
                message => "$tweet->{user}->{screen_name} $tweet->{text}"
            ];
            my %headers = map { $_ => $req->header($_), } $req->headers->header_field_names;
            http_post $req->uri, $req->content, headers => \%headers, sub {};
        }
    },
    on_error => sub {
        $cv->send();
    },
    on_eof => sub {
        $cv->send();
    },
);

$cv->recv;
exit;

AnyEvent、AnyEvent::Twitter::Stream、AnyEvent::HTTPなどのモジュールのおかげでこんなに短くてもばっちり動いてくれます。
実際のスクリプトは、on_followイベントを拾ってフォローしている人数が少ない人には自動でフォロー返ししてあげたりとかする部分が追加されていたりします。

こんな小さいスクリプトが自宅サーバーで常時10個以上起動しているため、落ちると結構困ります。